# Root path
#
#  in: /Users/fbucek/Documents/Spaceti/common/example-app/server-sdk ( PWD )
# out: /Users/fbucek/Documents/Spaceti/common/example-app/
ROOT=$$replace(PWD, server-sdk, "")

# Getting 'subpath'
#
#  in: /Users/fbucek/Documents/Spaceti/common/server-sdk/src/testapp
# out: /src/testapp
SUBPATH=$$replace(_PRO_FILE_PWD_, $$ROOT, "")

# Getting 'base root output'
#
#  in: /Users/fbucek/_temp_/build-server-sdk-5_9_8-Debug/src/testapp
# out: /Users/fbucek/_temp_/build-server-sdk-5_9_8-Debug
ROOT_OUT=$$replace(OUT_PWD, $$SUBPATH, "")


#message("ROOT           :" $$ROOT)
#message("OUT_PWD        :" $$OUT_PWD)
#message("PWD            :" $$PWD)
#message("_PRO_FILE_PWD_ :" $$_PRO_FILE_PWD_)
#message("SUBPATH        :" $$SUBPATH)
#message("ROOT_OUT       :" $$ROOT_OUT)

SDKDIR=$$ROOT_OUT/server-sdk/src/serversdk


win32:CONFIG(release, debug|release): LIBS += -L$$SDKDIR/release/ -lserversdk
else:win32:CONFIG(debug, debug|release): LIBS += -L$$SDKDIR/debug/ -lserversdk
else:unix: LIBS += -L$$SDKDIR/ -lserversdk

QT += network sql

INCLUDEPATH += $$shell_quote($$PWD/src/)
DEPENDPATH += $$shell_quote($$PWD/src/serversdk)

win32-g++:CONFIG(release, debug|release): PRE_TARGETDEPS += $$SDKDIR/release/libserversdk.a
else:win32-g++:CONFIG(debug, debug|release): PRE_TARGETDEPS += $$SDKDIR/debug/libserversdk.a
else:win32:!win32-g++:CONFIG(release, debug|release): PRE_TARGETDEPS += $$SDKDIR/release/serversdk.lib
else:win32:!win32-g++:CONFIG(debug, debug|release): PRE_TARGETDEPS += $$SDKDIR/debug/serversdk.lib
else:unix: PRE_TARGETDEPS += $$SDKDIR/libserversdk.a