message("OUT_PWD        :" $$OUT_PWD)
message("PWD            :" $$PWD)
message("_PRO_FILE_PWD_ :" $$_PRO_FILE_PWD_)
message("DESTDIR        :" $$DESTDIR)

# Getting 'subpath'
#
#  in: /Users/fbucek/Documents/Spaceti/common/server-sdk/src/testapp
# out: /src/testapp
SUBPATH=$$_PRO_FILE_PWD_
SUBPATH=$$replace(SUBPATH, $$PWD, "")
message("SUBPATH        :" $$SUBPATH)

# Getting 'base root output'
#
#  in: /Users/fbucek/_temp_/build-server-sdk-5_9_8-Debug/src/testapp
# out: /Users/fbucek/_temp_/build-server-sdk-5_9_8-Debug
ROOT_OUT=$$OUT_PWD
ROOT_OUT=$$replace(OUT_PWD, $$SUBPATH, "")
message("ROOT_OUT       :" $$ROOT_OUT)


SDKDIR=$$ROOT_OUT/src/serversdk


win32:CONFIG(release, debug|release): LIBS += -L$$SDKDIR/release/ -lserversdk
else:win32:CONFIG(debug, debug|release): LIBS += -L$$SDKDIR/debug/ -lserversdk
else:unix: LIBS += -L$$SDKDIR/ -lserversdk


INCLUDEPATH += $$PWD/src/
DEPENDPATH += $$PWD/src/serversdk

win32-g++:CONFIG(release, debug|release): PRE_TARGETDEPS += $$SDKDIR/release/libserversdk.a
else:win32-g++:CONFIG(debug, debug|release): PRE_TARGETDEPS += $$SDKDIR/debug/libserversdk.a
else:win32:!win32-g++:CONFIG(release, debug|release): PRE_TARGETDEPS += $$SDKDIR/release/serversdk.lib
else:win32:!win32-g++:CONFIG(debug, debug|release): PRE_TARGETDEPS += $$SDKDIR/debug/serversdk.lib
else:unix: PRE_TARGETDEPS += $$SDKDIR/libserversdk.a